メインコンテンツまでスキップ

スタック操作と関数呼び出し命令

関数呼び出しでは、戻り先を保持し、必要なレジスターを退避し、ローカル変数の領域を確保します。そのために使われるスタックは、Windowsのx86・x64・ARM64で、基本的に低いアドレスへ向かって拡張されます。

ただし、戻りアドレスの保存方法は命令セットによって異なります。以下は共通サンプルのMSVCビルドをCDBで確認した出力です。x86はフレームポインターを残す/O2 /Ob0 /Oy-、x64・ARM64は/O2 /Ob0を使用しています。

スタックポインターと基本命令​

目的x86x64ARM64
スタックポインターesprspsp
領域確保sub esp,Nsub rsp,Nsub sp,sp,#N
領域解放add esp,Nadd rsp,Nadd sp,sp,#N
レジスターの退避pushpushstr・stpなど
レジスターの復元poppopldr・ldpなど
直接呼び出しcallcallbl
戻り先スタック上スタック上x30(LR)。必要に応じてスタックへ退避

sub sp,sp,#Nなどは領域を予約するだけで、その内容を0にする操作ではありません。スタック上に残っていた値が、現在の関数に有効な引数やポインターとは限りません。

x86のPUSH・POP・CALL・RET​

通常の32ビットpush eaxはespを4減らし、その位置へeaxを書き込みます。pop eaxは先頭の4バイトを読み取り、espを4増やします。

通常の関数呼び出しに使うcallは、次の命令のアドレスを戻りアドレスとしてスタックへ積み、呼び出し先へ移ります。retはそのアドレスを取り出して戻ります。

int call_pair()
{
int total = add_values(10, 20);
return add_stdcall(total, 3);
}

add_valuesは通常のC関数、add_stdcallは__stdcallの2引数関数です。宣言と実装は呼び出し規約に掲載しています。

0:000> uf sample!call_pair
sample!call_pair:
003f1040 6a03 push 3
003f1042 6a14 push 14h
003f1044 6a0a push 0Ah
003f1046 e8d5ffffff call sample!add_values (003f1020)
003f104b 83c408 add esp,8
003f104e 50 push eax
003f104f e8bcffffff call sample!add_stdcall (003f1010)
003f1054 c3 ret

add_valuesの最初の命令の位置では、次の配置になります。

位置内容
[esp]戻りアドレス
[esp+4]第1引数:10
[esp+8]第2引数:20

add esp,8は呼び出し側で2引数分を解放する操作です。その後のpush eaxで戻り値30を積み、先に積んでおいた3と合わせてadd_stdcallへ渡します。後者はret 8で戻りアドレスを取り出すと同時に引数分も解放します。両者を混同すると、スタックの位置を誤って解釈します。

プロローグとエピローグ​

次は引数を調べるためのframe_probeの、先頭と末尾だけの抜粋です。計算部分は省略しています。

0:000> uf sample!frame_probe
sample!frame_probe:
003f1130 55 push ebp
003f1131 8bec mov ebp,esp
003f1133 83ec0c sub esp,0Ch
003f1136 8b5508 mov edx,dword ptr [ebp+8]
003f1139 8b450c mov eax,dword ptr [ebp+0Ch]
003f113c 03c2 add eax,edx
003f113e 8945f4 mov dword ptr [ebp-0Ch],eax
003f1171 8be5 mov esp,ebp
003f1173 5d pop ebp
003f1174 c3 ret

入口の準備処理をプロローグ、出口の復元処理をエピローグと呼びます。この例ではプロローグの後、[ebp]に保存したebp、[ebp+4]に戻りアドレス、[ebp+8]に第1引数があります。ebpより下側の領域はローカル変数などに利用できます。

ただし最適化によりフレームポインターが省略される場合があります。ebpが常にフレームの基点であるという前提ではなく、実際の命令とシンボル情報を確認します。

x64の戻りアドレスとシャドウスペース​

x64の通常のcallは8バイトの戻りアドレスをスタックへ積みます。Windowsの標準的なx64呼び出し規約では、呼び出し側が32バイトのシャドウスペースを確保し、通常はcallを実行する直前のrspを16バイト境界に合わせます。

同じcall_pairのx64出力です。ufが追跡した末尾呼び出し先の関数表示は省略しています。

0:000:AMD64> uf sample!call_pair
sample!call_pair:
00007ff6`81521040 4883ec28 sub rsp,28h
00007ff6`81521044 ba14000000 mov edx,14h
00007ff6`81521049 b90a000000 mov ecx,0Ah
00007ff6`8152104e e8cdffffff call sample!add_values (00007ff6`81521020)
00007ff6`81521053 8bc8 mov ecx,eax
00007ff6`81521055 ba03000000 mov edx,3
00007ff6`8152105a 4883c428 add rsp,28h
00007ff6`8152105e e9adffffff jmp sample!add_stdcall (00007ff6`81521010)

0x28はシャドウスペースの0x20バイトと、アラインメント調整の8バイトです。既に別の領域確保やレジスター退避がある関数では必要量が変わるため、固定の値として暗記するより、呼び出し直前の配置を追うとよいでしょう。

add_valuesの結果をecxへ移し、edxへ3を設定した後、確保した領域を戻してjmpしています。これは末尾呼び出しで、add_stdcallはこの関数の呼び出し元へ戻ります。x64では__stdcall指定も通常のx64規約を使い、x86のようなret 8にはなりません。

呼び出し先に入った直後、まだrspを変更していない時点の配置は次のとおりです。

位置内容
[rsp]戻りアドレス
[rsp+8]~[rsp+27h]32バイトのシャドウスペース
[rsp+28h]第5引数がある場合のスロット

シャドウスペースは、rcx・rdx・r8・r9のコピーが自動で保存される場所ではありません。呼び出し先は必要な場合だけ保存します。内容をそのまま第1~第4引数と解釈しないことが重要です。

ARM64のBL・LR・RET​

ARM64のblは、次の命令のアドレスをx30(LR)へ保存します。x86・x64のcallと異なり、戻りアドレスを自動でスタックへ積むわけではありません。引数は主にレジスターで渡されます。

別の関数を呼び出さない単純なリーフ関数なら、LRをスタックへ退避せず戻れる場合があります。

0:000> uf sample!add_values
sample!add_values:
00007ff6`7bef4020 0b010000 add w0,w0,w1
00007ff6`7bef4024 d65f03c0 ret

一方、別の関数をblで呼び出すとLRが上書きされるため、呼び出し元へ戻るためのLRを保持する必要があります。

0:000> uf sample!call_pair
sample!call_pair:
00007ff6`7bef4040 f81f0ffe str lr,[sp,#-0x10]!
00007ff6`7bef4044 52800281 mov w1,#0x14
00007ff6`7bef4048 52800140 mov w0,#0xA
00007ff6`7bef404c 97fffff5 bl sample!add_values (00007ff6`7bef4020)
00007ff6`7bef4050 52800061 mov w1,#3
00007ff6`7bef4054 97ffffef bl sample!add_stdcall (00007ff6`7bef4010)
00007ff6`7bef4058 f84107fe ldr lr,[sp],#0x10
00007ff6`7bef405c d65f03c0 ret

この例のstrはspを16減らし、LRを8バイト保存します。ldrはLRを復元後、spを16増やします。Windows ARM64のスタックは16バイトアラインメントを維持するので、退避する値が8バイトでも確保量は16バイトです。通常のARM64呼び出しに、Windows x64と同じ32バイトのシャドウスペースはありません。

実際の関数ではローカル変数や追加の退避領域を確保し、フレームポインターの設定順序も変わります。戻りアドレス保護に関係する命令が含まれる場合もあるため、上の短い形だけに当てはめないようにします。

スタック上のローカル変数を推定する​

ソースや完全なPDBがない場合でも、プロローグとメモリーへの書き込みから、ローカル領域の候補を絞れる場合があります。ただし、スタックにある値を型や名前まで一意に復元できるわけではありません。

ここでは呼び出し規約の記事と同じframe_probeを使います。引数は11、22、33、44、55で、ローカル配列は最初に{33, 77, 55}、別関数から戻った後は{33, 143, 55}になります。totalは66です。以下のメモリーとdvは、途中で保存したmiddle.dmpを再度開いた実測結果です。

x86:EBPを基準に対応付ける​

上のプロローグではpush ebp; mov ebp,espの後、12バイトを確保しています。続くmov [ebp-0Ch],eaxへの書き込みとソースを照合すると、local[0]がebp-0x0cにあると確認できます。関数全体にはebp-8とebp-4への書き込みもあります。

0:000> dv /t /v
02effd3c int first = 0n11
02effd40 int second = 0n22
02effd44 int third = 0n33
02effd48 int fourth = 0n44
02effd4c int fifth = 0n55
02effd28 int [3] local = int [3]
@eax int total = 0n66

0:000> dd @ebp-0xc L3
02effd28 00000021 0000008f 00000037

dv /t /vは型と格納場所を表示します。localはスタック上ですが、totalはeaxにあり、ローカル変数だからといってスタック上とは限りません。

このビルドでは[ebp]が保存したEBP、[ebp+4]が戻りアドレス、[ebp+8]以降が引数です。/Oy-を付けないビルドではフレームポインターが省略される場合があり、同じ対応をそのまま使うことはできません。

x64:現在のRSPと、入口からの変化を追う​

0:000:AMD64> uf sample!frame_probe
sample!frame_probe:
00007ff6`81521140 4883ec38 sub rsp,38h
00007ff6`81521144 8d0411 lea eax,[rcx+rdx]
00007ff6`81521147 89442420 mov dword ptr [rsp+20h],eax
00007ff6`8152114b 438d0408 lea eax,[r8+r9]
00007ff6`8152114f 89442424 mov dword ptr [rsp+24h],eax
00007ff6`81521153 8b442460 mov eax,dword ptr [rsp+60h]
00007ff6`81521157 03c8 add ecx,eax
00007ff6`81521159 89442428 mov dword ptr [rsp+28h],eax
00007ff6`8152115d e83e000000 call sample!identity (00007ff6`815211a0)
00007ff6`81521162 8b4c2424 mov ecx,dword ptr [rsp+24h]
00007ff6`81521166 03c8 add ecx,eax
00007ff6`81521168 894c2424 mov dword ptr [rsp+24h],ecx
00007ff6`8152116c cc int 3
00007ff6`8152116d 8b542428 mov edx,dword ptr [rsp+28h]
00007ff6`81521171 8b442424 mov eax,dword ptr [rsp+24h]
00007ff6`81521175 03d0 add edx,eax
00007ff6`81521177 8b442420 mov eax,dword ptr [rsp+20h]
00007ff6`8152117b 03c2 add eax,edx
00007ff6`8152117d 4883c438 add rsp,38h
00007ff6`81521181 c3 ret

sub rsp,38hの後、rsp+0x20、+0x24、+0x28へ4バイトずつ書いています。初期値を作る計算と、呼び出し後に同じ場所を読み書きする命令から、配列の位置を追えます。

int 3の位置の基準このビルドでの用途
rsp+0x00~rsp+0x1fidentity呼び出し用のシャドウスペース
rsp+0x20local[0]
rsp+0x24local[1]
rsp+0x28local[2]
rsp+0x38frame_probeの戻りアドレス
rsp+0x60呼び出し元から渡された第5引数
0:000:AMD64> dd @rsp+0x20 L3
0000007b`7b57fa30 00000021 0000008f 00000037

0:000:AMD64> dps @rsp+0x38 L1
0000007b`7b57fa48 00007ff6`8152120c sample!main+0x2c

現在のrsp+0x28と、入口のrsp+0x28は別の場所です。このサンプルではlocal[2]も第5引数も55なので、値が一致するだけでは位置の解釈が正しい証拠になりません。

ARM64:フレームポインターを設定しない例も読む​

frame_probeの先頭から停止位置までを抜粋します。

0:000> uf sample!frame_probe
sample!frame_probe:
00007ff6`7bef4100 f81f0ffe str lr,[sp,#-0x10]!
00007ff6`7bef4104 d10043ff sub sp,sp,#0x10
00007ff6`7bef4108 0b010009 add w9,w0,w1
00007ff6`7bef410c 0b030048 add w8,w2,w3
00007ff6`7bef4110 290023e9 stp w9,w8,[sp]
00007ff6`7bef4114 0b040000 add w0,w0,w4
00007ff6`7bef4118 b9000be4 str w4,[sp,#8]
00007ff6`7bef411c 94000019 bl sample!identity (00007ff6`7bef4180)
00007ff6`7bef4120 b94007e8 ldr w8,[sp,#4]
00007ff6`7bef4124 0b000108 add w8,w8,w0
00007ff6`7bef4128 b90007e8 str w8,[sp,#4]
00007ff6`7bef412c d43e0000 brk #0xF000

最初にLRのために16バイト、続いてローカル領域のために16バイト確保しています。現在のsp、sp+4、sp+8が配列要素、sp+0x10が退避したLRです。stp w9,w8,[sp]は32ビット値を2個保存するので、8バイトの書き込みです。

0:000> dd @sp L3
00000075`7df7fae0 00000021 0000008f 00000037

0:000> dps @sp+0x10 L1
00000075`7df7faf0 00007ff6`7bef41e8 sample!main+0x28

この関数にはmov fp,spがありません。現在のfpを、この関数のローカル領域の基点として使うことはできません。また、レジスターのLRはidentityから戻る位置へ上書きされています。frame_probe自身の呼び出し元は、保存したLRとアンワインド情報から確認します。

ソースや変数名がない場合の推定手順​

  1. kやknで対象フレームを特定し、必要なら.frame /r 番号で選びます。変数を読む前に、どのフレームのコンテキストかを確認します。
  2. ufとアンワインド情報から、スタック確保量、保存レジスター、戻りアドレスの位置を分けます。
  3. スタック相対のロード・ストアを追い、各位置が何バイトで、いつ初期化され、どこへ渡されるかを確認します。leaやaddでローカル領域のアドレスを別関数へ渡す命令も手掛かりです。
  4. PDBがあればdv /t /vの格納場所と照合し、なければddやdpsで候補を確認します。数値が似ているだけで変数名や型を断定しないようにします。
  5. 確認できたオフセットとアクセス幅を記録し、確定できない意味付けは推定として扱います。

確保領域には、ローカル変数以外にも、引数の退避、呼び出し先への引数、シャドウスペース、アラインメント、セキュリティCookieなどが含まれます。最適化により同じスロットが別の変数に再利用されたり、変数そのものが消えたりする場合もあります。sub rsp,NのNを、そのままローカル変数の合計サイズと解釈しないことが重要です。

コールスタックを復元する仕組み​

デバッガーは、単にスタック上の数値を列挙しているわけではありません。x64やARM64では、関数のプロローグでどの領域を確保し、何を保存したかを表すアンワインド情報などを使い、呼び出し元のスタックポインターや保存レジスターを復元します。

そのため、次のような状況でコールスタックが不完全になることがあります。

  • 戻りアドレスや保存レジスターが破壊されている
  • モジュールやシンボル、必要なメモリーが取得できていない
  • 手書きコードや動的生成コードのアンワインド情報が不足している
  • 末尾呼び出しやインライン化により、元のソースとフレーム数が異なる

kなどのスタック表示と、生のスタックメモリーの両方を確認すると、破損か情報不足かを区別する手掛かりになります。ただし、スタック中にコードアドレスらしい値があるだけでは、それが有効な戻りアドレスとは断定できません。

RETでクラッシュした場合​

ret付近のクラッシュでは、スタック破壊、呼び出し規約の不一致、戻りアドレスの破損などが候補になります。ARM64ならLRの保存・復元も確認します。

戻りアドレス破壊の影響で命令フェッチに失敗した場合、例外の命令ポインターがretではなく、不正な戻り先を指していることもあります。最終的な停止位置だけでなく、例外レコードと直前の制御移動を照合します。

また、深い再帰や大きなローカル変数によりスタックを使い切るスタックオーバーフローは、戻りアドレスの上書きとは別の問題です。例外コードとスタックの反復パターンを確認して切り分けるとよいでしょう。

参考資料​